home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / vol7n7.arc / PP707.ARC / HTOL.ASM next >
Assembly Source File  |  1987-12-15  |  3KB  |  85 lines
  1.         name    HTOL
  2.         page    55,132
  3.         title   HTOL - Hex ASCII to long integer
  4.  
  5. ;
  6. ; HTOL.ASM - convert hexadecimal ASCII string 
  7. ;            to long (32-bit) integer.
  8. ;
  9. ; Copyright (C) 1988 Ziff Communications Co.
  10. ; PC Magazine * Ray Duncan
  11. ; 
  12. ; Call with:    DS:SI = address of string
  13. ;
  14. ; Returns:      DX:AX = result (high word in DX)
  15. ;               DS:SI = address+1 of terminator 
  16. ;
  17. ;               other registers preserved
  18. ;
  19. ; Like the C library 'atol', this routine gives no 
  20. ; warning in the event of overflow, and terminates 
  21. ; on the first unconvertable character.
  22. ;
  23.  
  24. _TEXT   segment word public 'CODE'
  25.  
  26.         assume  cs:_TEXT
  27.  
  28.         public  htol                    ; make HTOL available
  29.                                         ; to the Linker
  30.  
  31. htol    proc    near                    ; Convert hex ASCII string
  32.                                         ; to 32-bit binary integer.
  33.  
  34.         push    cx                      ; save register
  35.         xor     cx,cx                   ; set forming answer to zero
  36.         xor     dx,dx
  37.  
  38. htol1:  lodsb                           ; get next char., make sure
  39.                                         ; it is '0'-'9' or 'A'-'F'
  40.  
  41.         cmp     al,'0'
  42.         jb      htol3                   ; exit if char < '0'
  43.  
  44.         cmp     al,'9'
  45.         jbe     htol2                   ; proceed if char '0'-'9'
  46.  
  47.         or      al,20h                  ; fold char. to lower case.
  48.  
  49.         cmp     al,'f'
  50.         ja      htol3                   ; exit if > 'F' or 'f'
  51.  
  52.         cmp     al,'a'
  53.         jb      htol3                   ; exit if < 'A' or 'a'
  54.  
  55.         add     al,9                    ; else add fudge factor
  56.                                         ; for digits 'A'-'F'
  57.  
  58. htol2:                                  ; add this digit to
  59.                                         ; forming answer...
  60.  
  61.         shl     cx,1                    ; first shift current answer 
  62.         rcl     dx,1                    ; left by 4 bits...
  63.         shl     cx,1
  64.         rcl     dx,1            
  65.         shl     cx,1
  66.         rcl     dx,1            
  67.         shl     cx,1
  68.         rcl     dx,1            
  69.         and     ax,0fh                  ; isolate binary value 0-A
  70.                                         ; from ASCII character code,
  71.         or      cx,ax                   ; add to the forming answer.
  72.  
  73.         jmp     htol1                   ; get next character
  74.  
  75. htol3:  mov     ax,cx                   ; return DX:AX = value
  76.         pop     cx                      ; restore register
  77.         ret                             ; back to caller
  78.  
  79. htol    endp
  80.  
  81. _TEXT   ends
  82.  
  83.         end
  84.  
  85.